\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.

\* SPSS syntax to accompany paper entitled "Using SPSS to Analyze Complex Survey Data: A Primer".

\* Journal: Journal of Modern Applied Statistical Methods (2019, Volume 18, Issue 1).

\* Authors: Danjie Zou, Jennifer E.V. Lloyd, and Jennifer L. Baumbusch.

\* University of British Columbia.

\* Available from: http://blogs.ubc.ca/jenniferlloyd/syntax/.

\* Correspondence to: jennifer.lloyd@ubc.ca.

\* April 6, 2020.

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.

\* Suggested citation: Danjie Zou, Jennifer E.V. Lloyd, and Jennifer L. Baumbusch (2019). SPSS syntax to accompany paper entitled "Using SPSS to Analyze Complex Survey Data: A Primer". Retrieved from http://blogs.ubc.ca/jenniferlloyd/.

\* NOTE: Ideally, the syntax commands presented below should be executed one block by one block for the purpose of practice, rather than being executed as one entire run.

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

**\* Part 1: Basic operations.**

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

\* 1.1.

GET FILE = 'E:\Data\AHS5.sav'.

\* 1.2.

DATASET NAME ahs5.

\* 1.3.

DATASET ACTIVATE ahs5.

\*1.4.

DATASET CLOSE ahs5.

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

**\* Part 2: Plan file.**

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

\*This part is omitted because the plan file is not SPSS syntax. Rather, it is a XML file.

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

**\* Part 3: Descriptive analyses: Frequencies.**

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

\*3.1.

DATASET ACTIVATE ahs5.

\*3.2.

CSTABULATE

 /PLAN FILE='E:\Data\AHS\_plan.csaplan' /\*3.2.1

 /TABLES VARIABLES= Q1AgeGroup Q24Grade /\*3.2.2

 /SUBPOP TABLE=Q4Female DISPLAY=LAYERED /\*3.2.3

 /CELLS POPSIZE TABLEPCT /\*3.2.4

 /STATISTICS SE CV CIN(95) COUNT DEFF DEFFSQRT CUMULATIVE /\*3.2.5

 /MISSING SCOPE=TABLE CLASSMISSING=EXCLUDE /\*3.2.6 .

\* Inline comments start with '/\*' and do not end with a period, unless it is the comment of the final subcommand.

\* If the comment ends with a period, it will be treated as the end of command, which may cause error.

\* The period in the last subcommand after inline comment '/\*3.2.6' is necessary, which is regarded as the end of the entire command.

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

**\* Part 4: Descriptive analyses: Descriptives.**

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

\*4.1.

CSDESCRIPTIVES

 /PLAN FILE='E:\Data\AHS\_plan.csaplan' /\*4.1.1

 /SUMMARY VARIABLES = Q1Age /\*4.1.2

 /MEAN TTEST=10 /\*4.1.3

 /SUM TTEST=100 /\*4.1.4

 /RATIO NUMERATOR=Q1Age DENOMINATOR=Q24Grade TTEST=5 /\*4.1.5

 /STATISTICS SE CV COUNT POPSIZE DEFF DEFFSQRT CIN(95) /\*4.1.6

 /MISSING SCOPE=ANALYSIS CLASSMISSING=EXCLUDE /\*4.1.7 .

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

**\* Part 5: Inferential analyses: General Linear Model (GLM).**

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

CSGLM Q29Health BY Q4Female WITH Q1Age /\*5.1

 /PLAN FILE='E:\Data\AHS\_plan.csaplan' /\*5.1.1

 /DOMAIN VARIABLE=Q30Allergy(1) /\*5.1.2

 /MODEL Q4Female Q1Age Q4Female\*Q1Age /\*5.1.3

 /INTERCEPT INCLUDE=YES SHOW=YES /\*5.1.4

 /STATISTICS PARAMETER SE CINTERVAL TTEST DEFF DEFFSQRT /\*5.1.5

 /PRINT COVB CORB SUMMARY VARIABLEINFO SAMPLEINFO /\*5.1.6

 /TEST TYPE=F PADJUST=LSD /\*5.1.7

 /MISSING CLASSMISSING=EXCLUDE /\*5.1.8

 /CRITERIA CILEVEL=95 /\*5.1.9 .

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

**\* Part 6: Macros: DO Loop.**

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

DEFINE !fre (conditions= !CMDEND) /\*6.1

 !DO !condition !IN (!conditions) /\*6.2

 DATASET ACTIVATE ahs5. /\*6.3

 CSTABULATE /\*6.4

 /PLAN FILE='E:\Data\AHS\_plan.csaplan' /\*6.4.1

 /TABLES VARIABLES= !condition /\*6.4.2

 /CELLS POPSIZE ROWPCT /\*6.4.3

 /STATISTICS SE CV CIN(99) COUNT DEFF DEFFSQRT /\*6.4.4

 /MISSING SCOPE=TABLE CLASSMISSING=INCLUDE. /\*6.4.5

 !DOEND. /\*6.5

!ENDDEFINE. /\*6.6 .

!fre conditions = condition\_1 condition\_2 condition\_3 condition\_4. /\*6.7

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

**\* Part 6: Macros: DO Loop /** Inline comments removed.

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

DEFINE !fre (conditions= !CMDEND)

 !DO !condition !IN (!conditions)

 DATASET ACTIVATE ahs5.

 CSTABULATE

 /PLAN FILE='E:\Data\AHS\_plan.csaplan'

 /TABLES VARIABLES= !condition

 /CELLS POPSIZE ROWPCT

 /STATISTICS SE CV CIN(99) COUNT DEFF DEFFSQRT

 /MISSING SCOPE=TABLE CLASSMISSING=INCLUDE.

 !DOEND.

!ENDDEFINE.

!fre conditions = condition\_1 condition\_2 condition\_3 condition\_4.

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

**\* Part 7: Macros: Nested DO Loop.**

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

DEFINE !crosstab (conditions= !CHAREND("/") / vars= !CMDEND) /\*7.1

 !DO !var !IN (!vars) /\*7.2

 !DO !condition !IN (!conditions) /\*7.3

 CSTABULATE /\*7.4

 /PLAN FILE='E:\Data\AHS\_plan.csaplan' /\*7.4.1

 /TABLES VARIABLES= !condition BY !var /\*7.4.2

 /CELLS POPSIZE ROWPCT /\*7.4.3

 /STATISTICS SE CV CIN(99) COUNT DEFF DEFFSQRT /\*7.4.4

 /MISSING SCOPE=TABLE CLASSMISSING=INCLUDE. /\*7.4.5

 !DOEND. /\*7.5

 !DOEND. /\*7.6

!ENDDEFINE. /\*7.7 .

!crosstab conditions = condition\_1 condition\_2 condition\_3 condition\_4 / vars= var\_1 var\_2 var\_3. /\*7.8

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

**\* Part 7: Macros: Nested DO Loop /** Inline comments removed.

**\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.**

DEFINE !crosstab (conditions= !CHAREND("/") / vars= !CMDEND)

 !DO !var !IN (!vars)

 !DO !condition !IN (!conditions)

 CSTABULATE

 /PLAN FILE='E:\Data\AHS\_plan.csaplan'

 /TABLES VARIABLES= !condition BY !var

 /CELLS POPSIZE ROWPCT

 /STATISTICS SE CV CIN(99) COUNT DEFF DEFFSQRT

 /MISSING SCOPE=TABLE CLASSMISSING=INCLUDE.

 !DOEND.

 !DOEND.

!ENDDEFINE.

!crosstab conditions = condition\_1 condition\_2 condition\_3 condition\_4 / vars= var\_1 var\_2 var\_3.

\*This is the end of syntax file.